ale_linters/less/lessc.vim

   1 " Author: zanona <https://github.com/zanona>, w0rp <devw0rp@gmail.com>
   2 " Description: This file adds support for checking Less code with lessc.
   3
   4 call ale#Set('less_lessc_executable', 'lessc')
   5 call ale#Set('less_lessc_options', '')
   6 call ale#Set('less_lessc_use_global', get(g:, 'ale_use_global_executables', 0))
   7
   8 function! ale_linters#less#lessc#GetCommand(buffer) abort
   9     return '%e --no-color --lint'
  10     \   . ' --include-path=' . ale#Escape(expand('#' . a:buffer . ':p:h'))
  11     \   . ale#Pad(ale#Var(a:buffer, 'less_lessc_options'))
  12     \   . ' -'
  13 endfunction
  14
  15 function! ale_linters#less#lessc#Handle(buffer, lines) abort
  16     let l:dir = expand('#' . a:buffer . ':p:h')
  17     " Matches patterns like the following:
  18     let l:pattern = '^\(\w\+\): \(.\{-}\) in \(.\{-}\) on line \(\d\+\), column \(\d\+\):$'
  19     let l:output = []
  20
  21     for l:match in ale#util#GetMatches(a:lines, l:pattern)
  22         let l:item = {
  23         \   'lnum': l:match[4] + 0,
  24         \   'col': l:match[5] + 0,
  25         \   'text': l:match[2],
  26         \   'type': 'E',
  27         \}
  28
  29         if l:match[3] isnot# '-'
  30             let l:item.filename = ale#path#GetAbsPath(l:dir, l:match[3])
  31         endif
  32
  33         call add(l:output, l:item)
  34     endfor
  35
  36     return l:output
  37 endfunction
  38
  39 call ale#linter#Define('less', {
  40 \   'name': 'lessc',
  41 \   'executable': {b -> ale#path#FindExecutable(b, 'less_lessc', [
  42 \       'node_modules/.bin/lessc',
  43 \   ])},
  44 \   'command': function('ale_linters#less#lessc#GetCommand'),
  45 \   'callback': 'ale_linters#less#lessc#Handle',
  46 \   'output_stream': 'stderr',
  47 \})