ale_linters/lua/luac.vim

   1 " Author: Jon Xie https://github.com/xiejiangzhi
   2 " Description: luac linter for lua files
   3
   4 call ale#Set('lua_luac_executable', 'luac')
   5
   6 function! ale_linters#lua#luac#Handle(buffer, lines) abort
   7     " Matches patterns line the following:
   8     "
   9     " luac: stdin:5: '=' expected near ')'
  10     " luac: stdin:8: ')' expected (to close '(' at line 6) near '123'
  11     let l:pattern = '\v^.*:(\d+): (.+)$'
  12     let l:output = []
  13
  14     for l:match in ale#util#GetMatches(a:lines, l:pattern)
  15         call add(l:output, {
  16         \   'lnum': l:match[1] + 0,
  17         \   'type': 'E',
  18         \   'text': l:match[2],
  19         \})
  20     endfor
  21
  22     return l:output
  23 endfunction
  24
  25 call ale#linter#Define('lua', {
  26 \   'name': 'luac',
  27 \   'executable': {b -> ale#Var(b, 'lua_luac_executable')},
  28 \   'command': '%e -p -',
  29 \   'output_stream': 'stderr',
  30 \   'callback': 'ale_linters#lua#luac#Handle',
  31 \})