ale_linters/rego/opacheck.vim

   1 " Description: opa check for rego files
   2
   3 call ale#Set('rego_opacheck_executable', 'opa')
   4 call ale#Set('rego_opacheck_options', '')
   5
   6 function! ale_linters#rego#opacheck#GetExecutable(buffer) abort
   7     return ale#Var(a:buffer, 'rego_opacheck_executable')
   8 endfunction
   9
  10 function! ale_linters#rego#opacheck#GetCommand(buffer) abort
  11     let l:options = ale#Var(a:buffer, 'rego_opacheck_options')
  12
  13     return ale#Escape(ale_linters#rego#opacheck#GetExecutable(a:buffer))
  14     \   . ' check %s:h --format json '
  15     \   . (!empty(l:options) ? ' ' . l:options : '')
  16 endfunction
  17
  18 function! ale_linters#rego#opacheck#Handle(buffer, lines) abort
  19     let l:output = []
  20
  21     let l:errors = ale#util#FuzzyJSONDecode(a:lines, {'errors': []})
  22     let l:dir = expand('#' . a:buffer . ':p:h')
  23     let l:file = expand('#' . a:buffer . ':p')
  24
  25     for l:error in l:errors['errors']
  26         if has_key(l:error, 'location')
  27             call add(l:output, {
  28             \   'filename': ale#path#GetAbsPath(l:dir, l:error['location']['file']),
  29             \   'lnum': l:error['location']['row'],
  30             \   'col': l:error['location']['col'],
  31             \   'text': l:error['message'],
  32             \   'code': l:error['code'],
  33             \   'type': 'E',
  34             \})
  35         else
  36             call add(l:output, {
  37             \   'filename': l:file,
  38             \   'lnum': 0,
  39             \   'col': 0,
  40             \   'text': l:error['message'],
  41             \   'code': l:error['code'],
  42             \   'type': 'E',
  43             \})
  44         endif
  45     endfor
  46
  47     return l:output
  48 endfunction
  49
  50 call ale#linter#Define('rego', {
  51 \   'name': 'opacheck',
  52 \   'output_stream': 'both',
  53 \   'executable': function('ale_linters#rego#opacheck#GetExecutable'),
  54 \   'command': function('ale_linters#rego#opacheck#GetCommand'),
  55 \   'callback': 'ale_linters#rego#opacheck#Handle',
  56 \})