ale_linters/solidity/solc.vim

   1 " Author: Karl Bartel <karl42@gmail.com> - http://karl.berlin/
   2 " Description: Report solc compiler errors in Solidity code
   3
   4 call ale#Set('solidity_solc_executable', 'solc')
   5 call ale#Set('solidity_solc_options', '')
   6
   7 function! ale_linters#solidity#solc#Handle(buffer, lines) abort
   8     " Matches patterns like the following:
   9     " Error: Expected ';' but got '('
  10     "    --> /path/to/file/file.sol:1:10:)
  11     let l:pattern = '\v(Error|Warning): (.*)$'
  12     let l:line_and_column_pattern = '\v\.sol:(\d+):(\d+):'
  13     let l:output = []
  14
  15     for l:line in a:lines
  16         let l:match = matchlist(l:line, l:pattern)
  17
  18         if len(l:match) == 0
  19             let l:match = matchlist(l:line, l:line_and_column_pattern)
  20
  21             if len(l:match) > 0
  22                 let l:index = len(l:output) - 1
  23                 let l:output[l:index]['lnum'] = l:match[1] + 0
  24                 let l:output[l:index]['col'] = l:match[2] + 0
  25             endif
  26         else
  27             let l:isError = l:match[1] is? 'Error'
  28
  29             call add(l:output, {
  30             \   'lnum': 0,
  31             \   'col': 0,
  32             \   'text': l:match[2],
  33             \   'type': l:isError ? 'E' : 'W',
  34             \})
  35         endif
  36     endfor
  37
  38     return l:output
  39 endfunction
  40
  41 function! ale_linters#solidity#solc#GetCommand(buffer) abort
  42     let l:executable = ale#Var(a:buffer, 'solidity_solc_executable')
  43
  44     return l:executable . ale#Pad(ale#Var(a:buffer, 'solidity_solc_options')) . ' %s'
  45 endfunction
  46
  47 call ale#linter#Define('solidity', {
  48 \   'name': 'solc',
  49 \   'executable': {b -> ale#Var(b, 'solidity_solc_executable')},
  50 \   'command': function('ale_linters#solidity#solc#GetCommand'),
  51 \   'callback': 'ale_linters#solidity#solc#Handle',
  52 \   'output_stream': 'stderr',
  53 \})