ale_linters/verilog/vlog.vim

   1 " Author:      John Gentile <johncgentile17@gmail.com>
   2 " Description: Adds support for Mentor Graphics Questa/ModelSim `vlog` Verilog compiler/checker
   3
   4 call ale#Set('verilog_vlog_executable', 'vlog')
   5 " See `$ vlog -h` for more options
   6 call ale#Set('verilog_vlog_options', '-quiet -lint')
   7
   8 function! ale_linters#verilog#vlog#GetCommand(buffer) abort
   9     return '%e ' . ale#Pad(ale#Var(a:buffer, 'verilog_vlog_options')) . ' %t'
  10 endfunction
  11
  12 function! ale_linters#verilog#vlog#Handle(buffer, lines) abort
  13     "Matches patterns like the following:
  14     "** Warning: add.v(7): (vlog-2623) Undefined variable: C.
  15     "** Error: file.v(1): (vlog-13294) Identifier must be declared with a port mode: C.
  16     let l:pattern = '^**\s\(\w*\): \([a-zA-Z0-9\-\.\_\/ ]\+\)(\(\d\+\)):\s\+\(.*\)'
  17     let l:output = []
  18
  19     for l:match in ale#util#GetMatches(a:lines, l:pattern)
  20         call add(l:output, {
  21         \   'lnum': l:match[3] + 0,
  22         \   'type': l:match[1] is? 'Error' ? 'E' : 'W',
  23         \   'text': l:match[4],
  24         \   'filename': l:match[2],
  25         \})
  26     endfor
  27
  28     "Matches patterns like the following:
  29     "** Warning: (vlog-2623) add.v(7): Undefined variable: C.
  30     "** Error: (vlog-13294) file.v(1): Identifier must be declared with a port mode: C.
  31     " let l:pattern = '^**\s\(\w*\):[a-zA-Z0-9\-\.\_\/ ]\+(\(\d\+\)):\s\+\(.*\)'
  32     let l:pattern = '^**\s\(\w*\):\s\([^)]*)\) \([a-zA-Z0-9\-\.\_\/ ]\+\)(\(\d\+\)):\s\+\(.*\)'
  33
  34     for l:match in ale#util#GetMatches(a:lines, l:pattern)
  35         call add(l:output, {
  36         \   'lnum': l:match[4] + 0,
  37         \   'type': l:match[1] is? 'Error' ? 'E' : 'W',
  38         \   'text': l:match[2] . ' ' . l:match[5],
  39         \   'filename': l:match[3],
  40         \})
  41     endfor
  42
  43     return l:output
  44 endfunction
  45
  46 call ale#linter#Define('verilog', {
  47 \   'name': 'vlog',
  48 \   'output_stream': 'stdout',
  49 \   'executable': {b -> ale#Var(b, 'verilog_vlog_executable')},
  50 \   'command': function('ale_linters#verilog#vlog#GetCommand'),
  51 \   'callback': 'ale_linters#verilog#vlog#Handle',
  52 \})