autoload/ale/fixers/autoflake.vim

   1 " Author: circld <circld1@gmail.com>
   2 " Description: Fixing files with autoflake.
   3
   4 call ale#Set('python_autoflake_executable', 'autoflake')
   5 call ale#Set('python_autoflake_use_global', get(g:, 'ale_use_global_executables', 0))
   6 call ale#Set('python_autoflake_options', '')
   7 call ale#Set('python_autoflake_auto_pipenv', 0)
   8 call ale#Set('python_autoflake_auto_poetry', 0)
   9 call ale#Set('python_autoflake_auto_uv', 0)
  10
  11 function! ale#fixers#autoflake#GetExecutable(buffer) abort
  12     if (ale#Var(a:buffer, 'python_auto_pipenv') || ale#Var(a:buffer, 'python_autoflake_auto_pipenv'))
  13     \ && ale#python#PipenvPresent(a:buffer)
  14         return 'pipenv'
  15     endif
  16
  17     if (ale#Var(a:buffer, 'python_auto_poetry') || ale#Var(a:buffer, 'python_autoflake_auto_poetry'))
  18     \ && ale#python#PoetryPresent(a:buffer)
  19         return 'poetry'
  20     endif
  21
  22     if (ale#Var(a:buffer, 'python_auto_uv') || ale#Var(a:buffer, 'python_autoflake_auto_uv'))
  23     \ && ale#python#UvPresent(a:buffer)
  24         return 'uv'
  25     endif
  26
  27     return ale#python#FindExecutable(a:buffer, 'python_autoflake', ['autoflake'])
  28 endfunction
  29
  30 function! ale#fixers#autoflake#Fix(buffer) abort
  31     let l:executable = ale#fixers#autoflake#GetExecutable(a:buffer)
  32
  33     let l:exec_args = l:executable =~? '\(pipenv\|poetry\|uv\)$'
  34     \   ? ' run autoflake'
  35     \   : ''
  36
  37     let l:options = ale#Var(a:buffer, 'python_autoflake_options')
  38
  39     return {
  40     \   'command': ale#Escape(l:executable) . l:exec_args
  41     \       . (!empty(l:options) ? ' ' . l:options : '')
  42     \       . ' --in-place '
  43     \       . ' %t',
  44     \   'read_temporary_file': 1,
  45     \}
  46 endfunction