test/test_organize_imports.vader

   1 Before:
   2   call ale#test#SetDirectory('/testplugin/test')
   3   call ale#test#SetFilename('dummy.txt')
   4
   5   let g:old_filename = expand('%:p')
   6   let g:Callback = ''
   7   let g:expr_list = []
   8   let g:message_list = []
   9   let g:handle_code_action_called = 0
  10   let g:code_actions = []
  11   let g:options = {}
  12   let g:capability_checked = ''
  13   let g:conn_id = v:null
  14   let g:InitCallback = v:null
  15
  16   runtime autoload/ale/lsp_linter.vim
  17   runtime autoload/ale/lsp.vim
  18   runtime autoload/ale/util.vim
  19   runtime autoload/ale/organize_imports.vim
  20   runtime autoload/ale/code_action.vim
  21
  22   function! ale#lsp_linter#StartLSP(buffer, linter, Callback) abort
  23     let g:conn_id = ale#lsp#Register('executable', '/foo/bar', '', {})
  24     call ale#lsp#MarkDocumentAsOpen(g:conn_id, a:buffer)
  25
  26     if a:linter.lsp is# 'tsserver'
  27         call ale#lsp#MarkConnectionAsTsserver(g:conn_id)
  28     endif
  29
  30     let l:details = {
  31     \ 'command': 'foobar',
  32     \ 'buffer': a:buffer,
  33     \ 'connection_id': g:conn_id,
  34     \ 'project_root': '/foo/bar',
  35     \}
  36
  37     let g:InitCallback = {-> ale#lsp_linter#OnInit(a:linter, l:details, a:Callback)}
  38   endfunction
  39
  40   function! ale#lsp#HasCapability(conn_id, capability) abort
  41     let g:capability_checked = a:capability
  42
  43     return 1
  44   endfunction
  45
  46   function! ale#lsp#RegisterCallback(conn_id, callback) abort
  47     let g:Callback = a:callback
  48   endfunction
  49
  50   function! ale#lsp#Send(conn_id, message) abort
  51     call add(g:message_list, a:message)
  52
  53     return 42
  54   endfunction
  55
  56   function! ale#util#Execute(expr) abort
  57     call add(g:expr_list, a:expr)
  58   endfunction
  59
  60   function! ale#code_action#HandleCodeAction(code_action, options) abort
  61     let g:handle_code_action_called = 1
  62     AssertEqual g:ale_save_hidden || !&hidden, get(a:options, 'should_save')
  63     call add(g:code_actions, a:code_action)
  64   endfunction
  65
  66 After:
  67   if g:conn_id isnot v:null
  68     call ale#lsp#RemoveConnectionWithID(g:conn_id)
  69   endif
  70
  71   call ale#references#SetMap({})
  72   call ale#test#RestoreDirectory()
  73   call ale#linter#Reset()
  74
  75   unlet! g:capability_checked
  76   unlet! g:InitCallback
  77   unlet! g:old_filename
  78   unlet! g:conn_id
  79   unlet! g:Callback
  80   unlet! g:message_list
  81   unlet! g:expr_list
  82   unlet! b:ale_linters
  83   unlet! g:options
  84   unlet! g:code_actions
  85   unlet! g:handle_code_action_called
  86
  87   runtime autoload/ale/lsp_linter.vim
  88   runtime autoload/ale/lsp.vim
  89   runtime autoload/ale/util.vim
  90   runtime autoload/ale/organize_imports.vim
  91   runtime autoload/ale/code_action.vim
  92
  93 Execute(Other messages for the tsserver handler should be ignored):
  94   call ale#organize_imports#HandleTSServerResponse(1, {'command': 'foo'})
  95   AssertEqual g:handle_code_action_called, 0
  96
  97 Execute(Failed organizeImports responses should be handled correctly):
  98   call ale#organize_imports#HandleTSServerResponse(
  99   \ 1,
 100   \ {'command': 'organizeImports', 'request_seq': 3}
 101   \)
 102   AssertEqual g:handle_code_action_called, 0
 103
 104 Execute(Code actions from tsserver should be handled):
 105   call ale#organize_imports#HandleTSServerResponse(1, {
 106   \ 'command': 'organizeImports',
 107   \ 'request_seq': 3,
 108   \ 'success': v:true,
 109   \ 'body': [],
 110   \})
 111   AssertEqual g:handle_code_action_called, 1
 112   AssertEqual [{
 113   \   'description': 'Organize Imports',
 114   \   'changes': [],
 115   \}], g:code_actions
 116
 117 Given typescript(Some typescript file):
 118   foo
 119   somelongerline
 120   bazxyzxyzxyz
 121
 122 Execute(tsserver organize imports requests should be sent):
 123   call ale#linter#Reset()
 124   runtime ale_linters/typescript/tsserver.vim
 125
 126   ALEOrganizeImports
 127
 128   " We shouldn't register the callback yet.
 129   AssertEqual '''''', string(g:Callback)
 130
 131   AssertEqual type(function('type')), type(g:InitCallback)
 132   call g:InitCallback()
 133
 134   AssertEqual
 135   \ 'function(''ale#organize_imports#HandleTSServerResponse'')',
 136   \ string(g:Callback)
 137
 138   AssertEqual
 139   \ [
 140   \   ale#lsp#tsserver_message#Change(bufnr('')),
 141   \   [0, 'ts@organizeImports', {
 142   \     'scope': {
 143   \         'type': 'file',
 144   \         'args': {
 145   \             'file': expand('%:p'),
 146   \         },
 147   \     },
 148   \   }]
 149   \ ],
 150   \ g:message_list
 151
 152 Given python(Some Python file):
 153   foo
 154   somelongerline
 155   bazxyzxyzxyz
 156
 157 Execute(Should result in error message for LSP):
 158   call ale#linter#Reset()
 159   runtime ale_linters/python/pylsp.vim
 160   let b:ale_linters = ['pylsp']
 161
 162   ALEOrganizeImports
 163
 164   " We shouldn't register the callback yet.
 165   AssertEqual '''''', string(g:Callback)
 166
 167   AssertEqual type(function('type')), type(g:InitCallback)
 168   call g:InitCallback()
 169
 170   AssertEqual [
 171   \  'echom ''OrganizeImports currently only works with tsserver''',
 172   \], g:expr_list