.vim/bundle/ale/ale_linters/cuda/nvcc.vim

   1 " Author: blahgeek <i@blahgeek.com>
   2 " Description: NVCC linter for cuda files
   3
   4 call ale#Set('cuda_nvcc_executable', 'nvcc')
   5 call ale#Set('cuda_nvcc_options', '-std=c++11')
   6
   7 function! ale_linters#cuda#nvcc#GetCommand(buffer) abort
   8     return '%e -cuda'
   9     \   . ale#Pad(ale#c#IncludeOptions(ale#c#FindLocalHeaderPaths(a:buffer)))
  10     \   . ale#Pad(ale#Var(a:buffer, 'cuda_nvcc_options'))
  11     \   . ' %s -o ' . g:ale#util#nul_file
  12 endfunction
  13
  14 function! ale_linters#cuda#nvcc#HandleNVCCFormat(buffer, lines) abort
  15     " Look for lines like the following.
  16     "
  17     " test.cu(8): error: argument of type "void *" is incompatible with parameter of type "int *"
  18     let l:pattern = '\v^([^:\(\)]+):?\(?(\d+)\)?:(\d+)?:?\s*\w*\s*(error|warning): (.+)$'
  19     let l:output = []
  20
  21     for l:match in ale#util#GetMatches(a:lines, l:pattern)
  22         let l:item = {
  23         \   'lnum': str2nr(l:match[2]),
  24         \   'type': l:match[4] =~# 'error' ? 'E' : 'W',
  25         \   'text': l:match[5],
  26         \   'filename': fnamemodify(l:match[1], ':p'),
  27         \}
  28
  29         if !empty(l:match[3])
  30             let l:item.col = str2nr(l:match[3])
  31         endif
  32
  33         call add(l:output, l:item)
  34     endfor
  35
  36     return l:output
  37 endfunction
  38
  39 call ale#linter#Define('cuda', {
  40 \   'name': 'nvcc',
  41 \   'output_stream': 'stderr',
  42 \   'executable': {b -> ale#Var(b, 'cuda_nvcc_executable')},
  43 \   'command': function('ale_linters#cuda#nvcc#GetCommand'),
  44 \   'callback': 'ale_linters#cuda#nvcc#HandleNVCCFormat',
  45 \   'lint_file': 1,
  46 \})