after/ftplugin/mkd.vim

   1 " folding for Markdown headers, both styles (atx- and setex-)
   2 " http://daringfireball.net/projects/markdown/syntax#header
   3 "
   4 " this code can be placed in file
   5 "   $HOME/.vim/after/ftplugin/markdown.vim
   6 "
   7 " original version from Steve Losh's gist: https://gist.github.com/1038710
   8
   9 func! Foldexpr_markdown(lnum)
  10     if (a:lnum == 1)
  11         let l0 = ''
  12     else
  13         let l0 = getline(a:lnum-1)
  14     endif
  15
  16     let l1 = getline(a:lnum)
  17
  18     let l2 = getline(a:lnum+1)
  19
  20     if  l2 =~ '^==\+\s*'
  21         " next line is underlined (level 1)
  22         return '>1'
  23     elseif l2 =~ '^--\+\s*'
  24         " next line is underlined (level 2)
  25         return '>2'
  26     elseif l1 =~ '^#'
  27         " don't include the section title in the fold
  28         return '-1'
  29     elseif l0 =~ '^#'
  30         " current line starts with hashes
  31         return '>'.matchend(l0, '^#\+')
  32     else
  33         " keep previous foldlevel
  34         return '='
  35     endif
  36 endfunc
  37
  38
  39 if !exists("g:vim_markdown_folding_disabled")
  40   setlocal foldexpr=Foldexpr_markdown(v:lnum)
  41   setlocal foldmethod=expr
  42
  43   "---------- everything after this is optional -----------------------
  44   " change the following fold options to your liking
  45   " see ':help fold-options' for more
  46   setlocal foldenable
  47   setlocal foldlevel=0
  48   setlocal foldcolumn=0
  49   set foldmethod=expr
  50   set foldopen-=search
  51 endif