syntax/markdown.vim

   1 " Vim syntax file
   2 " Language:     Markdown
   3 " Maintainer:   Ben Williams <benw@plasticboy.com>
   4 " URL:          http://plasticboy.com/markdown-vim-mode/
   5 " Remark:       Uses HTML syntax file
   6 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
   7
   8
   9 " Read the HTML syntax to start with
  10 if version < 600
  11   so <sfile>:p:h/html.vim
  12 else
  13   runtime! syntax/html.vim
  14
  15   if exists('b:current_syntax')
  16     unlet b:current_syntax
  17   endif
  18 endif
  19
  20 if version < 600
  21   syntax clear
  22 elseif exists("b:current_syntax")
  23   finish
  24 endif
  25
  26 " don't use standard HiLink, it will not work with included syntax files
  27 if version < 508
  28   command! -nargs=+ HtmlHiLink hi link <args>
  29 else
  30   command! -nargs=+ HtmlHiLink hi def link <args>
  31 endif
  32
  33 syn spell toplevel
  34 syn case ignore
  35 syn sync linebreaks=1
  36
  37 "additions to HTML groups
  38 syn region htmlItalic start="\\\@<!\*\S\@=" end="\S\@<=\\\@<!\*" keepend oneline
  39 syn region htmlItalic start="\(^\|\s\)\@<=_\|\\\@<!_\([^_]\+\s\)\@=" end="\S\@<=[^\\]_\|[^\\]_\S\@=" keepend oneline
  40 syn region htmlBold start="\S\@<=\*\*\|\*\*\S\@=" end="\S\@<=\*\*\|\*\*\S\@=" keepend oneline
  41 syn region htmlBold start="\S\@<=__\|__\S\@=" end="\S\@<=__\|__\S\@=" keepend oneline
  42 syn region htmlBoldItalic start="\S\@<=\*\*\*\|\*\*\*\S\@=" end="\S\@<=\*\*\*\|\*\*\*\S\@=" keepend oneline
  43 syn region htmlBoldItalic start="\S\@<=___\|___\S\@=" end="\S\@<=___\|___\S\@=" keepend oneline
  44
  45 " [link](URL) | [link][id] | [link][] | ![image](URL)
  46 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
  47 syn region mkdID matchgroup=mkdDelimiter        start="\["    end="\]" contained oneline
  48 syn region mkdURL matchgroup=mkdDelimiter       start="("     end=")"  contained oneline
  49 syn region mkdLink matchgroup=mkdDelimiter      start="\\\@<!!\?\[" end="\]\ze\s*[[(]" contains=@mkdNonListItem,@Spell nextgroup=mkdURL,mkdID skipwhite oneline
  50
  51 " Autolink without angle brackets.
  52 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
  53 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
  54 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
  55
  56 " Autolink with parenthesis.
  57 syntax region  mkdInlineURL matchgroup=mkdDelimiter start="(\(https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*)\)\@=" end=")"
  58
  59 " Autolink with angle brackets.
  60 syn region mkdInlineURL matchgroup=mkdDelimiter start="\\\@<!<\(\(https\?\|ftp\|git\|coap\|doi\|javascript\|aaas\?\|about\|acap\|cap\|cid\|crid\|data\|dav\|dict\|dns\|file\|geo\|go\|gopher\|h323\|iax\|icap\|im\|imap\|info\|ipp\|iris\|iris.beep\|iris.xpc\|iris.xpcs\|iris.lwz\|ldaps\?\|mailto\|mid\|msrp\|msrps\|mtqp\|mupdate\|news\|nfs\|ni\|nih\|nntp\|opaquelocktoken\|pop\|pres\|rtsp\|service\|session\|shttp\|sieve\|sip\|sips\|sms\|snmp,soap.beep\|soap.beeps\|tag\|tel\|telnet\|tftp\|thismessage\|tn3270\|tip\|tv\|urn\|vemmi\|wss\?\|xcon\|xcon-userid\|xmlrpc.beep\|xmlrpc.beeps\|xmpp\|z39.50r\|z39.50s\|adiumxtra\|afp\|afs\|aim\|apt,attachment\|aw\|beshare\|bitcoin\|bolo\|callto\|chrome,chrome-extension\|com-eventbrite-attendee\|content\|cvs,dlna-playsingle\|dlna-playcontainer\|dtn\|dvb\|ed2k\|facetime\|feed\|finger\|fish\|gg\|gizmoproject\|gtalk\|hcp\|icon\|ipn\|irc6\|ircs\?\|itms\|jar\|jms\|keyparc\|lastfm\|magnet\|maps\|market,message\|mms\|ms-help\|msnim\|mumble\|mvn\|notes\|oid\|palm\|paparazzi\|platform\|proxy\|psyc\|query\|res\|resource\|rmi\|rsync\|rtmp\|secondlife\|sftp\|sgn\|skype\|smb\|soldat\|spotify\|ssh\|steam\|svn\|teamspeak\|things\|udp\|unreal\|ut2004\|ventrilo\|view-source\|webcal\|wtai\|wyciwyg\|xfire\|xri\|ymsgr'\):\/\/[^> ]*>\)\@=" end=">"
  61
  62 " Link definitions: [id]: URL (Optional Title)
  63 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
  64 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
  65 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
  66 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
  67 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
  68
  69 "define Markdown groups
  70 syn match  mkdLineContinue ".$" contained
  71 syn match  mkdLineBreak    /  \+$/
  72 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,mkdLineContinue,@Spell
  73 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
  74 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
  75 syn region mkdCode         start=/^\s*```\s*[0-9A-Za-z_+-]*\s*$/          end=/^\s*```\s*$/
  76 syn region mkdCode         start=/\s*\~\~[^\~]*/              end=/[^\~]*\~\~\s*/
  77 syn region mkdCode         start=/^\s*\~\~\~\s*[0-9A-Za-z_+-]*\s*$/          end=/^\s*\~\~\~\s*$/
  78 syn region mkdCode         start="<pre[^>]*>"              end="</pre>"
  79 syn region mkdCode         start="<code[^>]*>"             end="</code>"
  80 syn region mkdFootnote     start="\[^"                     end="\]"
  81 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
  82 syn match  mkdCode         /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
  83 syn region mkdListItemLine matchgroup=mkdListItem start="^\s*\%([-*+]\|\d\+\.\)\s\+" end="$" contains=@mkdNonListItem,@Spell
  84 syn region mkdNonListItemBlock start="\(\%^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@!\|\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!\)" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
  85 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
  86 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
  87 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
  88 syn match  mkdRule         /^\s*-\{3,}$/
  89 syn match  mkdRule         /^\s*\*\{3,5}$/
  90
  91 "HTML headings
  92 syn region htmlH1       start="^\s*#"                   end="$" contains=@Spell
  93 syn region htmlH2       start="^\s*##"                  end="$" contains=@Spell
  94 syn region htmlH3       start="^\s*###"                 end="$" contains=@Spell
  95 syn region htmlH4       start="^\s*####"                end="$" contains=@Spell
  96 syn region htmlH5       start="^\s*#####"               end="$" contains=@Spell
  97 syn region htmlH6       start="^\s*######"              end="$" contains=@Spell
  98 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
  99 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
 100
 101 " YAML frontmatter
 102 if get(g:, 'vim_markdown_frontmatter', 0)
 103   syn include @yamlTop syntax/yaml.vim
 104   syn region Comment matchgroup=mkdDelimiter start="\%^---$" end="^---$" contains=@yamlTop
 105 endif
 106
 107 if get(g:, 'vim_markdown_math', 0)
 108   syn include @tex syntax/tex.vim
 109   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$" end="\$" contains=@tex
 110   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$\$" end="\$\$" contains=@tex
 111 endif
 112
 113 syn cluster mkdNonListItem contains=@htmlTop,htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdInlineURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdListItem,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6,mkdMath
 114
 115 "highlighting for Markdown groups
 116 HtmlHiLink mkdString        String
 117 HtmlHiLink mkdCode          String
 118 HtmlHiLink mkdFootnote      Comment
 119 HtmlHiLink mkdBlockquote    Comment
 120 HtmlHiLink mkdLineContinue  Comment
 121 HtmlHiLink mkdListItem      Identifier
 122 HtmlHiLink mkdRule          Identifier
 123 HtmlHiLink mkdLineBreak     Todo
 124 HtmlHiLink mkdFootnotes     htmlLink
 125 HtmlHiLink mkdLink          htmlLink
 126 HtmlHiLink mkdURL           htmlString
 127 HtmlHiLink mkdInlineURL     htmlLink
 128 HtmlHiLink mkdID            Identifier
 129 HtmlHiLink mkdLinkDef       mkdID
 130 HtmlHiLink mkdLinkDefTarget mkdURL
 131 HtmlHiLink mkdLinkTitle     htmlString
 132 HtmlHiLink mkdDelimiter     Delimiter
 133
 134 let b:current_syntax = "mkd"
 135
 136 delcommand HtmlHiLink
 137 " vim: ts=8