.vim/bundle/ale/ale_linters/markdown/mdl.vim

   1 " Author: Steve Dignam <steve@dignam.xyz>, Josh Leeb-du Toit <joshleeb.com>
   2 " Description: Support for mdl, a markdown linter.
   3
   4 call ale#Set('markdown_mdl_executable', 'mdl')
   5 call ale#Set('markdown_mdl_options', '')
   6
   7 function! ale_linters#markdown#mdl#GetExecutable(buffer) abort
   8     return ale#Var(a:buffer, 'markdown_mdl_executable')
   9 endfunction
  10
  11 function! ale_linters#markdown#mdl#GetCommand(buffer) abort
  12     let l:executable = ale_linters#markdown#mdl#GetExecutable(a:buffer)
  13     let l:exec_args = l:executable =~? 'bundle$'
  14     \   ? ' exec mdl'
  15     \   : ''
  16
  17     let l:options = ale#Var(a:buffer, 'markdown_mdl_options')
  18
  19     return ale#Escape(l:executable) . l:exec_args
  20     \   . ' -j' . (!empty(l:options) ? ' ' . l:options : '')
  21 endfunction
  22
  23 function! ale_linters#markdown#mdl#Handle(buffer, lines) abort
  24     let l:output = []
  25
  26     for l:error in ale#util#FuzzyJSONDecode(a:lines, [])
  27         call add(l:output, {
  28         \   'lnum': l:error['line'],
  29         \   'code': l:error['rule']  . '/' . join(l:error['aliases'], '/'),
  30         \   'text': l:error['description'],
  31         \   'type': 'W',
  32         \})
  33     endfor
  34
  35     return l:output
  36 endfunction
  37
  38 call ale#linter#Define('markdown', {
  39 \   'name': 'mdl',
  40 \   'executable': function('ale_linters#markdown#mdl#GetExecutable'),
  41 \   'command': function('ale_linters#markdown#mdl#GetCommand'),
  42 \   'callback': 'ale_linters#markdown#mdl#Handle'
  43 \})